Tippseite

VB-Homepage Tipp 150

Ermitteln, ob ein CD-ROM verfügbar ist

Genau 50 Tipps vorher, ging es um das Ermitteln von Datenträgereigenschaften, wie Cluster, verfügbarer Speicher u.s.w.
Natürlich haben Datenträger auch noch andere Eigenschaften, sind sie austauschbar oder fest installiert oder handelt es sich um ein CD-ROM.
Wenn Sie also nur wissen möchten, ob ein CD-ROM im System verfügbar ist,
dann ist dies Ihr Tipp.

1. Dazu benötigen wir wie immer ein frisches Projekt und im Abschnitt Allgemein/Deklarationen folgenden Code.
Private Declare Function GetDriveType Lib "kernel32" Alias "GetDriveTypeA" (ByVal nDrive As String) As Long
Private Declare Function GetLogicalDriveStrings Lib "kernel32" Alias "GetLogicalDriveStringsA" (ByVal nBufferLength As Long, ByVal lpBuffer As String) As Long
Private Const DRIVE_REMOVABLE = 2
Private Const DRIVE_FIXED = 3
Private Const DRIVE_REMOTE = 4
Private Const DRIVE_CDROM = 5
Private Const DRIVE_RAMDISK = 6

2. Fügen sie Ihrem Projekt einen CommandButton hinzu und definieren Sie in der Prozedur Click folgende Anweisungen.

Dim r&, allDrives$, JustOneDrive$, pos%, DriveType&
Dim CDfound As Integer
allDrives$ = Space$(64)
r& = GetLogicalDriveStrings(Len(allDrives$), allDrives$)
allDrives$ = Left$(allDrives$, r&)

Do
   pos% = InStr(allDrives$, Chr$(0))
   If pos% Then
      JustOneDrive$ = Left$(allDrives$, pos%)
      allDrives$ = Mid$(allDrives$, pos% + 1, Len(allDrives$))
      DriveType& = GetDriveType(JustOneDrive$)
      If DriveType& = DRIVE_CDROM Then
         CDfound% = True
         Exit Do
      End If
   End If
Loop Until allDrives$ = "" Or DriveType& = DRIVE_CDROM

If CDfound% Then
   Msgbox "CD-ROM verfügbar als Laufwerk : " & UCase$(JustOneDrive$)
Else
   Msgbox "Kein CD-ROM auf diesem System verfügbar."
End If

3. Das war es schon, nach dem Test mit F5 und dem Ausführen der Prozedur unter Command1/Click wird Ihnen das Ergebnis als Messagebox angezeigt.

Das dies weiter zu verfeinert geht und das man die selbe Prozedur auch zum Anzeigen der Eigenschaften aller Datenträger nutzen kann, haben Sie sicher schon gemerkt.

Tipp-Download

Quelle :